asm-debouncing-keypad

Switch debouncing 과 Keypad Interfacing - ASM

• Switch의 Bouncing 현상과 Debouncing 기술
• Switch Interfacing
• Switch를 닫(Closed)거나 열(Open) 때 발생하는 Bouncing 현상
• Hardware Debouncing
• Software Debouncing
• Time Delay를 이용한 Software Debouncing 프로그램 예
• External Interrupt와 Timer Interrupt를 이용한 Debouncing 예
• Keypad Interfacing
• 4 by 3 일반 전화기용 Keypad와 ATmega128의 Interfacing 예
• Key Scanning
• Key Switch를 press와 release 시 발생 하는 Bouncing 문제
• Key Switch를 Press 하거나 Release 할 때 입력 Port에 발생 하는 Bouncing 문제의 해결
• Keypad programming 예
• Switch debouncing 과 Keypad Interfacing 관련 페이지 보기
• ATmega128 I/O Port - ASM
• ATMega128 External Interrupt - ASM
• Serial I/O(UART) Communication - ASM

---

Switch의 Bouncing 현상과 Debouncing 기술

• Switch Interfacing
• Switch Interfacing Circuit 예
• PD0와 GND 사이에 Push Button Switch를 연결 한다.
• PD0를 Input Port로 설정 한다.
• Switch 가 Push 상태 일때 PD0는 0(Low) 상태가 되고,
• Switch 가 Release 상태 일때 1(High) 상태가 된다.


a) 외부 Pull Up 저항을 사용한 경우의 예.                       b) 프로세서 내부 Pull Up 저항을 사용한 경우의 예.



• Switch를 닫(Closed)거나 개방(Open) 할 때 발생하는 Bouncing 현상

Switch의 금속 접점은 이상적이지 않기 때문에 Switch를 Closed 하거나 Open 하는 순간에 아래 그림과 같이 Bouncing 현상이 발생 한다.



Bouncing은 Switch의 상태에 따라 대략 5mSec - 10mSec 사이에 발생 한다.

Bouncing 신호는 장치 오동작의 중요한 요인 이다.



• Hardware Debouncing
• Hardware Debouncing circuits

아래 그림a)와 같이 R-C Low Pass Filter 회로(Bouncing 신호는 Switch의 동작 속도에 비교 하면 높은 주파수 신호 이기 때문에 Low Pass Filter를 사용 하면 Bouncing 신호의 진폭만 크게 감소 한다.)를 사용 하면 Bouncing 신호의 진폭을 크게 감소 시킬 수 있다.

그러나 a) 회로에서는 Switch가 닫이는 순간 Switch가 Open 상태에서 C에 충전되었던 전하가 아주 짧은 시간에 Switch를 통하여 방전되면서 Switch에 큰 순간 전류(회로를 손상 시키는 원인이 됨)가 흐르게 된다.

Switch가 닫이는 순간 Switch에 흐르는 큰 전류에 의한 손상을 방지 하기 위하여 그림 b)와 같이 Switch와 직렬로 22옴 정도를 연결 한다.





a) R-C Low Pass Filter와 Schmitt Trigger 회로를 사용한 Debouncing circuit





b) 위 Debouncing circuit에서 발생하는 Switch 과도 전류 문제를 개선한 회로



• Schmitt Trigger 회로에 의한 Debouncing

아래 그림 b)와 같이 Bouncing 신호의 진폭을 R-C 회로를 사용하여 낮게 할 수 있다.

그러나 R-C 회로를 통과한 Bouncing 신호의 진폭이 입력 Port의 Vt(Gate 입력의 Low(0) High(1)을 구분 하는 경계 전압) 보다 높을 수 있기 때문에 아래 그림 a)와 같은 전달 특성을 같는 Schmitt Trigger 회로를 사용 하여 Noise Margin을 크게 한다.

그 결과 그림 b)에서와 같이 Switch 에서 발생한 Bouncing 신호를 R-C 회로와 Schmitt Trigger 회로를 사용 하여 그림 c)와 같이 제거 할 수 있게 된다.



a) Schmitt Trigger 회로의 전달 특성





b) Hardware Debouncing circuit의 입력 파형





c) Hardware Debouncing circuit의 출력 파형



• Software Debouncing
• Time Delay를 이용한 Debouncing 예

uP의 실행 속도에 충분한 여유가 있는 경우, Switch가 동작(Closed or Open)한 순간으로 부터 Bouncing 현상이 없어지는 시간 만큼 Delay 한 후에 Switch의 상태를 읽는 방법(Software적인 방법)으로 Bouncing 현상을 제거 할 수 있다.

아래 그림 a)는 Switch를 닫을 때(Press) 발생 하는 Bouncing 문제를 해결 하기 위한 예(Block diagram) 이고,

그림 b)는 Switch를 개방(Release) 할 때 발생 하는 Bouncing 문제를 해결 하기 위한 예(Block diagram) 이다.



a) Switch를 닫을 때(Press) Debouncing 예                       b) Switch를 개방 할 때(Release) Debouncing 예



• Gadfly loop와 Time Delay를 이용한 Debouncing 예

아래 Gadfly loop를 이용한 Debouncing 예는 위에서 설명한 Software debouncing 알고리즘을 개선한 방법 이다.



a) Gadfly loop와 Time Delay를 이용한 Debouncing 예



• External interrupt와 Timer interrupt를 이용한 Debouncing 예

External interrupt 입력 단자와 Timer interrupt를 사용 할 수 있는 Timer 가 있는 경우 아래와 같이 보다 효과 적으로 Bouncing 문제를 해결 할 수 있다. 이 방법을 이해 하기 위하여는 External interrupt와 Timer interrupt에 대한 이해가 필요 하다.

• External interrupt service routine
• External interrupt 입력 단자에 연결된 Switch를 동작(Press or Release) 시키면 External interrupt service routine이 실행 된다.
• 원하지 않는 Bouncing 신호에 의하여 Interrupt Service Routine이 다시 실행 되지 않도록 External interrupt를 Disable 상태로 한다.
• Timer interrupt에 사용 할 Timer의 Delay Time를 설정 한다. Timer의 Interrupt Service Routine은 여기서 설정한 Delay Time(약 10 - 16mSec) 후에 실행 된다.
• External interrupt service routine의 실행을 종료 한다.
• Timer interrupt service routine
• External interrupt service routine에서 설정한 Delay Time 후에 Timer interrupt Service routine이 실행 된다.
• Timer interrupt를 Disable 한다. Timer interrupt Routine은 다음 Switch 동작에 의하여 Switch External interrupt에서 Timer interrupt를 Enable 할 때 까지 실행 되지 않는다.
• 새로운 Switch 동작에 의하여 External interrupt routine이 실행 될 수 있도록 External interrupt를 Enable 한다.
• Switch의 상태(Pressed or Released)에 따른 동작을 실행 한다.
• Timer interrupt service routine의 실행을 종료 한다.


a) External interrupt이 발생 하였을 때의 처리                   b) Timer interrupt이 발생 하였을 때의 처리



• Time Delay를 이용한 Software Debouncing 프로그램 예
• Switch의 bouncing 현상을 관찰 하기 위한 프로그램 예: AVR_asm_sw_bounce_counter.zip
; [Add Project title here] ; ; Author: chowk ; Lab: KHU ; Date: 2022. 10. 10 .NOLIST .include "m128def.inc" ; Definition file for ATmega128 ; Interrupt Vectors Table ;.include "avr128_interrupt_table.inc" ; [Add all hardware information here] .DEVICE ATmega128 .LIST ; Program Constants ; ; Program Variables Definitions .def AC0 = r16 ; .def AC1 = r17 ; .def SW_STATUS_OLD = r18 ; ; SRAM Definitions .DSEG .ORG 0x0100 counter: .BYTE 1 ; Reserve 1 Byte to Global Variable ;vgWord: .BYTE 2 ; Reserve 2 Byte to Global Variable ;vgDWord: .BYTE 4 ; Reserve 4 Byte to Global Variable .CSEG ; Func: RESET Handler Routine RESET: ; Stack Pointer Init ldi AC0, LOW(RAMEND) out SPL, AC0 ldi AC0, HIGH(RAMEND) out SPH, AC0 rjmp MAIN ; Main Entry into program MAIN: ; I/O Port Init clr AC0 sts PORTF, AC0 ; Clear(Turn Off LED), PORTF : Memory Mapped I/O Port out DDRD, AC0 ; PORTD : I/O Maped Inputport ser AC0 out PORTD, AC0 ; Input Port PullUp sts DDRF, AC0 ; PORTF : Output Port ser SW_STATUS_OLD ; 이전 SW 상태를 SW가 Open 된 상태로 초기화 ; Global Variable Init ldi XL, LOW(counter) ldi XH, HIGH(counter) clr AC1 st X, AC1 ; counter = 0 LOOP: in AC0, PIND ; PD0 SW 상태 입력 andi AC0, $01 ; PD0 SW 상태 Testing breq SW_PUSHED ; 만약 SW 가 눌렸으면 SW_PUSHED로 ser SW_STATUS_OLD ; SW Opened rjmp LOOP SW_PUSHED: and SW_STATUS_OLD, SW_STATUS_OLD ; SW의 이전 상태 Test breq LOOP ; 만약 SW 가 눌린 상태가 계속 되고 있으면 무시 ; 만약 SW 가 이제 막 눌려 졌으면 LED의 상태를 Toggle 한다. clr SW_STATUS_OLD ; SW의 현재 상태를 Close로 ; counter 값을 읽어서 증가(1) 시키고 저장 한다. ldi XL, LOW(counter) ldi XH, HIGH(counter) ld AC1, X inc AC1 st X, AC1 sts PORTF, AC1 ; Counter 값을 LED에 출력 한다. rjmp LOOP ; Loop Indefinitly

• 실험을 위한 준비
• PD0에 Push button switch를 연결한다.
• PORTF에 저항(330Ω)과 LED Array(8Bits)를 연결한다.

참고자료: 8Bit-LED-array-module 제작 예

• 실험 방법
• Project(Project name: AVR_asm_sw_bounce_counter)를 생성 한다.
• 위 프로그램을 main.asm에 복사하고 저장한다.
• Build → Build Solution 를 실행 하면 main.asm File 이 Assemble 되어 AVR_asm_sw_bounce_counter.hex 파일이 생성된다.
• AVR_asm_sw_bounce_counter.hex 파일을 Target Board에 Upload 하고 프로그램을 실행한다.
• 실험: Push button switch(PD0)를 누르면 LED Array(8Bits)에 누른 회수가 2진수로 출력된다.

주: Debouncing를 기능이 없기 때문에 Push button switch(PD0)를 한번 눌러도 경우에 때라 누른 회수가 1 이상 증가하는 경우가 발생한다.



• Software time delay를 이용한 Software Debouncing 프로그램 프로그램 예: AVR_asm_sw_debounce_counter_soft.zip
; [Add Project title here] ; ; Author: chowk ; Lab: KHU ; Date: 2022. 10. 10 .NOLIST .include "m128def.inc" ; Definition file for ATmega128 ; Interrupt Vectors Table ;.include "avr128_interrupt_table.inc" ; [Add all hardware information here] .DEVICE ATmega128 .LIST ; Program Constants ; ; Program Variables Definitions .def AC0 = r16 ; .def AC1 = r17 ; .def SW_STATUS_OLD = r18 ; ; SRAM Definitions .DSEG .ORG 0x0100 ;vgByte: .BYTE 1 ; Reserve 1 Byte to Global Variable ;vgWord: .BYTE 2 ; Reserve 2 Byte to Global Variable ;vgDWord: .BYTE 4 ; Reserve 4 Byte to Global Variable counter: .BYTE 1 .CSEG ; Func: RESET Handler Routine RESET: ; Stack Pointer Init ldi AC0, LOW(RAMEND) out SPL, AC0 ldi AC0, HIGH(RAMEND) out SPH, AC0 rjmp MAIN ; Main Entry into program MAIN: ; I/O Port Init clr AC0 sts PORTF, AC0 ; Clear(Turn Off LED), PORTF : Memory Mapped I/O Port out DDRD, AC0 ; PORTD : I/O Maped Inputport ser AC0 out PORTD, AC0 ; Input Port PullUp sts DDRF, AC0 ; PORTF : Output Port ; 처음 시작 시 LED가 250mSec 동안 켜지도록 한다. sts PORTF, AC0 ldi AC0, 250 ; mSec Delay rcall mSecDelay clr AC0 sts PORTF, AC0 ser SW_STATUS_OLD ; 이전 SW 상태를 SW가 Open 된 상태로 초기화 ; Global Variable Init ldi XL, LOW(counter) ldi XH, HIGH(counter) clr AC1 st X, AC1 ; counter = 0 LOOP: in AC0, PIND ; PD0 SW 상태 입력 andi AC0, $01 ; PD0 SW 상태 Testing breq SW_PUSHED ; 만약 SW 가 눌렸으면 SW_PUSHED로 ser SW_STATUS_OLD ; SW Opened ldi AC0, 20 ; mSec Delay, Debouncing rcall mSecDelay rjmp LOOP SW_PUSHED: and SW_STATUS_OLD, SW_STATUS_OLD ; SW의 이전 상태 Test breq LOOP ; 만약 SW 가 눌린 상태가 계속 되고 있으면 무시 ; 만약 SW 가 이제 막 눌려 졌으면 LED의 상태를 Toggle 한다. clr SW_STATUS_OLD ; SW의 현재 상태를 Close로 ; counter 값을 읽어서 증가(1) 시키고 저장 한다. ldi XL, LOW(counter) ldi XH, HIGH(counter) ld AC1, X inc AC1 st X, AC1 sts PORTF, AC1 ; Counter 값을 LED에 출력 한다. ldi AC0, 20 ; mSec Delay, Debouncing rcall mSecDelay rjmp LOOP ; Loop Indefinitly ; Passing Argument ; AC0 : N mSec ; Return Value : Void mSecDelay: push AC0 push AC1 mov AC1,AC0 ldi AC0, 250 ; mLOOP: rcall uSecDelay ; 250uSec + rcall uSecDelay ; 250uSec + rcall uSecDelay ; 250uSec + rcall uSecDelay ; 250uSec = 1mSec dec AC1 ; brne mLOOP ; pop AC1 ; pop AC0 ; ret ; Passing Argument ; AC0 : N uSec ; Return Value : Void uSecDelay: push AC0 ; 2 cycle uLOOP: push AC0 ; 2 cycle + pop AC0 ; 2 cycle + push AC0 ; 2 cycle + pop AC0 ; 2 cycle + push AC0 ; 2 cycle + pop AC0 ; 2 cycle + nop ; 1 cycle + dec AC0 ; 1 cycle + brne uLoop ; 1 cycle = (15 + M1) cycle * 0.0625uSec = 1uSec pop AC0 ; 2 cycle ret

• 실험을 위한 준비
• PD0에 Push button switch를 연결한다.
• PORTF에 저항(330Ω)과 LED Array(8Bits)를 연결한다.

참고자료: 8Bit-LED-array-module 제작 예

• 실험 방법
• Project(Project name: AVR_asm_sw_debounce_counter_soft)를 생성 한다.
• 위 프로그램을 main.asm에 복사하고 저장한다.
• Build → Build Solution 를 실행 하면 main.asm File 이 Assemble 되어 AVR_asm_sw_debounce_counter_soft.hex 파일이 생성된다.
• AVR_asm_sw_debounce_counter_soft.hex 파일을 Target Board에 Upload 하고 프로그램을 실행한다.
• 실험: Push button switch(PD0)를 누르면 LED Array(8Bits)에 누른 회수가 2진수로 출력된다.

주: Debouncing를 기능을 구현하였기 때문에 Push button switch(PD0)를 누른 회수가 비교적 정확히 LED Array(8Bits)에 2진수로 출력된다.



• External Interrupt와 Timer Interrupt를 이용한 Debouncing 예

주: External Interrupt를 이용하여 Switch의 bouncing 현상을 관찰 하기 위한 프로그램 예는 "Switch를 누른 회수를 LED Bar에 2에 진수로 출력 하는 프로그림 예"를 참고바람.

• External Interrupt와 Timer Interrupt를 이용한 Debouncing 프로그램 예: AVR_asm_sw_debounce_counter_ext_int.zip
; [Add Project title here] ; ; Author: chowk ; Lab: KHU ; Date: 2022. 10. 10 .NOLIST .include "m128def.inc" ; Definition file for ATmega128 ; Interrupt Vectors Table .include "avr128_interrupt_table.inc" ; [Add all hardware information here] .DEVICE ATmega128 .LIST ; Program Constants ; ; Program Variables Definitions .def RG_TEMP = r0 ; Temporary Register .def RG_ZERO = r1 ; Zero .def AC0 = r16 ; .def AC1 = r17 ; ; SRAM Definitions .DSEG .ORG 0x0100 ;vgByte: .BYTE 1 ; Reserve 1 Byte to Global Variable ;vgWord: .BYTE 2 ; Reserve 2 Byte to Global Variable ;vgDWord: .BYTE 4 ; Reserve 4 Byte to Global Variable counter: .BYTE 1 .CSEG ; Func: RESET Handler Routine RESET: ; Stack Pointer Init ldi AC0, LOW(RAMEND) out SPL, AC0 ldi AC0, HIGH(RAMEND) out SPH, AC0 rjmp MAIN ; Main Entry into program MAIN: eor RG_ZERO, RG_ZERO ; r1 <- Zero ; I/O Port Init rcall port_init rcall timer1_init ; Global Variable Init ldi XL, LOW(counter) ldi XH, HIGH(counter) clr AC1 st X, AC1 ; counter = 0 LOOP: nop nop rjmp LOOP port_init: cli ;Clear Global Interrupt Flag ; I/O Port Init push AC0 ; Status register is not automatically stored when entering an interrupt routine in AC0, SREG ; Status register를 Save 한다. push AC0 out DDRD, RG_ZERO ; PORTD : I/O Maped Inputport ser AC0 out PORTD, AC0 ; Input Port PullUp sts DDRF, AC0 ; PORTF : Output Port ; PORTF : Memory Mapped I/O Port sts PORTF, RG_ZERO ; PORTF Turn off ; External Interrupt 0 flag ,clear in AC0, EIFR ori AC0, (1 << INTF0) out EIFR, AC0 ldi AC0, 0x02 ; INT0 Falling Edge Asynchronously Interrupt sts EICRA, AC0 ; External Interrupt 0 ,enable in AC0, EIMSK ori AC0, (1 << INT0) out EIMSK, AC0 pop AC0 out SREG, AC0 pop AC0 sei ; Set Global Interrupt Flag ret ; External Interrupt 0 INT0_vect: push AC0 ; External Interrupt 0 ,disable in AC0, EIMSK andi AC0, ~(1 << INTF0) out EIMSK, AC0 ; TCNT1 = 0; out TCNT1H, RG_ZERO out TCNT1L, RG_ZERO ; Timer1, Output Compare A Match Interrupt Enable in AC0, TIMSK ori AC0, (1 << OCIE1A) out TIMSK, AC0 pop AC0 reti ; Timer1, Output Compare A Match Interrupt 초기화 .equ OCR1A_20m = 312 // 64uSec * 312 = 20mSec timer1_init: push AC0 push AC1 ; Status register is not automatically stored when entering an interrupt routine in AC0, SREG ; Status register를 Save 한다. push AC0 ; (0 << COM1A1) | (0 << COM1A0) : Normal port operation, OCnA Disconnected. ; (0 << WGM13) | (1 << WGM12)| (0 << WGM11) | (0 << WGM10) : CTC, Top: OCR0A ; (0 << COM1A1) | (0 << COM1A0) | (0 << WGM11) | (0 << WGM10) out TCCR1A, RG_ZERO ; (1 << CS12) | (0 << CS11) | (1 << CS10) : 010 prescale ck/1024, Clock 주기 : 64uSec ldi AC0, (1 << CS12) | (0 << CS11) | (1 << CS10) | (0 << WGM13) | (1 << WGM12) out TCCR1B, AC0 ; OCR1A_500m = 7812, OCR1A_20m = 250 ldi AC1, HIGH(OCR1A_20m) ldi AC0, LOW(OCR1A_20m) out OCR1AH, AC1 out OCR1AL, AC0 ; TCNT1 = 0; out TCNT1H, RG_ZERO out TCNT1L, RG_ZERO ; Clear Output Compare A Match Flag in AC0, TIFR ori AC0, (1 << OCF1A) out TIFR, AC0 ; Timer1, Output Compare A Match Interrupt Disable in AC0, TIMSK andi AC0, ~(1 << OCIE1A) out TIMSK, AC0 pop AC0 out SREG, AC0 pop AC1 pop AC0 ret ; Timer1, Output Compare A Match Interrupt TIMER1_COMPA_vect: push AC0 push AC1 ; Timer1, Output Compare A Match Interrupt Disable in AC0, TIMSK andi AC0, ~(1 << OCIE1A) out TIMSK, AC0 in AC0, PIND ; Switch의 상태를 읽는다. andi AC0, $01 ; Switch(PD0) Testing brne TIMER1_NEXT ; Switch가 Open인 경우 PUSHED: ; Switch의 상태가 Open에서 Closed로 변경된 경우 NEXT1으로 Jmp ; counter 값을 읽어서 증가(1) 시키고 저장 한다. ldi XL, LOW(counter) ldi XH, HIGH(counter) ld AC1, X inc AC1 st X, AC1 sts PORTF, AC1 ; Counter 값을 LED에 출력 한다. TIMER1_NEXT: ; External Interrupt 0 flag ,clear in AC0, EIFR ori AC0, (1 << INTF0) out EIFR, AC0 ; External Interrupt 0 ,enable in AC0, EIMSK ori AC0, (1 << INT0) out EIMSK, AC0 pop AC1 pop AC0 reti

• 실험을 위한 준비
• PD0에 Push button switch를 연결한다.
• PORTF에 저항(330Ω)과 LED Array(8Bits)를 연결한다.

참고자료: 8Bit-LED-array-module 제작 예

• 실험 방법
• Project(Project name: AVR_asm_sw_debounce_counter_ext_int)를 생성 한다.
• 위 프로그램을 main.asm에 복사하고 저장한다.
• INT0, TIMER1_COMPA_vect Interrupt Vector 설정: "avr128_interrupt_table.inc"를 다운로드하여 아래 예와 같이 편집한다.
; Interrupt Vectors Table .CSEG .ORG $0000 ; Define start of Code segment jmp RESET ; Reset Handler jmp INT0_vect ; IRQ0 Handler reti ; IRQ1 Handler nop ... ... reti ; Timer1 Capture Handler nop jmp TIMER1_COMPA_vect ; Timer1 CompareA Handler reti ; Timer1 CompareB Handler nop ... ...
• Build → Build Solution 를 실행 하면 main.asm File 이 Assemble 되어 AVR_asm_sw_debounce_counter_ext_int.hex 파일이 생성된다.
• AVR_asm_sw_debounce_counter_ext_int.hex 파일을 Target Board에 Upload 하고 프로그램을 실행한다.
• 실험: Push button switch(PD0)를 누르면 LED Array(8Bits)에 누른 회수가 2진수로 출력된다.

주: Debouncing를 기능을 구현하였기 때문에 Push button switch(PD0)를 누른 회수가 비교적 정확히 LED Array(8Bits)에 2진수로 출력된다.

Keypad Interfacing

• 4 by 3 일반 전화기용 Keypad와 ATmega128의 Interfacing 예
• 아래 그림의 예에서는 Port C(PC4-PC7을 Output Port로 사용)와 Port E(PE4-Pe6 를 Input Port로 사용)를 Keypad 연결 Port로 사용 한다.
• PC4-PC7을 Output Port로 설정 한다.
• PE4-Pe6 를 Input Port로 설정 한다.
• Key Scanning 방식을 이용하여 Keypad의 상태(어느 Key가 Push 되었는지 확인 하고 해당 Key의 Code를 Return 하는 getkey() 함수를 작성 한다.
• Keypad 동작의 신뢰도를 높이기 위하여 Key 동작시 발생하는 Bouncing 문제를 고려 하여 프로그램을 작성 하여야 한다.(아래 프로그램 예를 참고 할 것.)


a) Keypad와 Atmega128 I/O Port Interfacing 회로도.                 b) 4 by 3 Keypad Pin.



• Key Scanning
• 출력 Port PC4 - PC7에 0111 패턴을 출력 하고 입력 Port PE4, PE5, PE6 읽으면 1,2,3 Key가 눌린 경우에만(1,2,3 이외에 다른 Key가 눌린 경우에는 PE4 - PE6 값이 1이 됨) 해당 위치의 Input port(PE4 - PE6)의 값이 0이 된다.
• 출력 Port PC4 - PC7에 1011 패턴을 출력 하고 입력 Port PE4 - PE6 읽으면 4,5,6 Key가 눌린 경우에만(4,5,6 이외 다른 Key가 눌린 경우에는 PE4 - PE6 값이 1이 됨) 해당 위치의 Input port(PE4 - PE6)의 값이 0이 된다.
• 위와 같이 출력 Port PC4 - PC7에 1101 패턴을 출력 하고 입력 Port PE4 - PE6을 읽으면 7,8,9 Key가 눌린 경우에만 해당 위치의 Input port(PE4 - PE6)의 값이 0이 되고, PC4-PC7에 1110 패턴을 출력 하고 입력 Port PE4 - PE6 읽으면 *,0,# Key가 눌린 경우에만 해당 위치의 Input port(PE4 - PE6)의 값이 0이 되기 때문에,
• 순차적으로 출력 Port에 0111, 1011, 1101, 1110 패턴을 출력 하면서 해당 Row에 있는 Key Switch의 상태를 읽어 어느 Key가 Press 되었는지 판단 한다.




그림 a) 4 By 3 Keypad Interface 회로와 Scanning Code 예



• key Switch를 press와 release 시 발생 하는 Bouncing 문제

Key Switch를 Press 하거나 Release 할 때 입력 Port에 발생 하는 파형 예(Bouncing 문제).




• Key Switch를 Press 하거나 Release 할 때 입력 Port에 발생 하는 Bouncing 문제의 해결
• Key Switch 접점의 불안정한 접속으로 Switch를 Press 하거나 Release 할 때 윗 그림과 같이 Bouncing 현상이 발생 한다.
• Bouncing 문제를 해결하기 위하여는 전자회로 적인 접근(RC Low Pass Filter 이용한 Hardware Debouncing)과,
• Bouncing 현상은 16mSec 이내 에서 발생 하기 때문에 첫 Press 또는 Release 신호 발생 후 일정 시간(16mSec 정도) 후에 다시 Switch의 상태를 읽어 Press 또는 Release 상태를 판단 하는 기술(Software Debouncing)을 사용 한다.


• Keypad programming 예:

Keypad로 부터 입력되는 문자를 UART 통신을 통하여 모니터(Console)에 출력 하는 실험 구성도


• 4 by 3 Keypad로 부터 Key 값을 읽어 모니터에 출력하는 프로그램 예: GCC_asm_keypad_uart_soft_basic.zip

Keypad 초기화 와 Key scaning 함수, get_key() 함수 예: GCC_asm_get_keypad_soft.s

// GCC_asm_keypad_soft.s // // Author: chowk // Lab: KHU // Date: 2012. 9. 14 // Keypad 제어 프로그램 // 이 프로그램은 Software Time Delay Routine을 사용한 Keypad 제어 프로그램이다. # ifndef atmega128 #define atmega128 # endif #define FOSC 16000000// Clock Speed #include <avr/io.h> // Definition file for ATmega128 #include "GCC_asm_soft_delay_u_mSec.h" #include "GCC_asm_uart.h" // SRAM Definitions #define _SFR_OFFSET 0 // Needed to subtract 0x20 from I/O addresses // [Add all hardware information here] // Program Constants // Program Variables Definitions #define RG_TEMP r0 // Temporary Register #define RG_ZERO r1 // Zero #define AC0 r16 // Accumulator Byte Rg 0 #define AC1 r17 // Accumulator Byte Rg 1 #define AC2 r18 // Accumulator Byte Rg 2 #define AC3 r19 // Accumulator Byte Rg 3 #define AC4 r20 // Accumulator Byte Rg 2 #define AC5 r21 // Accumulator Byte Rg 2 #define ACW0_L r2 // Accumulator Word Rg 0 Low #define ACW0_H r3 // Accumulator Word Rg 0 High #define ACW1_L r4 // Accumulator Word Rg 1 Low #define ACW1_H r5 // Accumulator Word Rg 1 High #define ACW2_L r6 // Accumulator Word Rg 2 Low #define ACW2_H r7 // Accumulator Word Rg 2 High #define ACW3_L r8 // Accumulator Word Rg 3 Low #define ACW3_H r9 // Accumulator Word Rg 3 High #define RG_ARG0_H r25 // Function Argument Word Rg 0 High #define RG_ARG0_L r24 // Function Argument Word Rg 0 Low #define RG_ARG1_H r23 // Function Argument Word Rg 1 High #define RG_ARG1_L r22 // Function Argument Word Rg 1 Low #define RG_ARG2_H r21 // Function Argument Word Rg 2 High #define RG_ARG2_L r20 // Function Argument Word Rg 2 Low #define ROW_PORT _SFR_IO_ADDR(PORTC) // Output Port #define ROW_PORT_DDR _SFR_IO_ADDR(DDRC) #define COL_PORT _SFR_IO_ADDR(PORTE) // Input Port #define COL_PORT_DDR _SFR_IO_ADDR(DDRE) #define COL_PORT_PIN _SFR_IO_ADDR(PINE) // Input Port #define ROW_MASK 0xf0 #define COL_MASK 0x70 #define NUM_ROWS 4 #define NUM_COLS 3 #define COL_TEST 0x40 // NUM_COLS = 3 : 0x40, NUM_COLS =4 : 0x80 #define DEBOUNCE_TIME 16 // 16mSec #define TRUE 0xff #define FALSE 0x00 .section .data keyPressed: .byte FALSE // Key 상태(Pressed or Release)을 저장하기 위한 변수 .section .text .global keypad_init,get_key // C Function : void keypad_port_init(void); keypad_port_init: push AC0 // ROW_PORT &= (~ROW_MASK) // Key Scan Output Port Enable <- 0 in AC0, ROW_PORT andi AC0, ~ROW_MASK out ROW_PORT, AC0 // Row Port Init(PC7-PC4 <- 0) // ROW_PORT_DDR |= ROW_MASK // Key Scan Output Port : PC4-PC7 in AC0, ROW_PORT_DDR ori AC0, ROW_MASK out ROW_PORT_DDR, AC0 // PORTE |= COL_MASK // External SW PullUp in AC0, COL_PORT // Input Port Pull Up ori AC0, COL_MASK out COL_PORT, AC0 // Col Port Init(PE6-PE4 <- 1) // COL_PORT_DDR &= (~COL_MASK) in AC0, COL_PORT_DDR andi AC0, ~COL_MASK out COL_PORT_DDR, AC0 // Col Port <- Input Port(PE6-PE4 <- Input Port) pop AC0 ret keypad_init: rcall keypad_port_init sts keyPressed, RG_ZERO // keyPressed의 초기 상태를 FALSE 로 설정 ret #define rowScanCode r18 #define colData r19 #define rowScanCounter r20 #define colScanCounter r21 #define pressedKeyNum r25 #define keyCode r24 // Key Scan // Return Value // RG_ARG0_L <- Char Code Data(8 Bit) // RG_ARG0_H <- Pressed Key Number // rcall key_scan // C Function : unsigned char key_scan( void ) ; keyCode 만 Return 하는 경우 // C Function : unsigned int key_scan( void ) ; keyCode를 LSB 1 Byte, // Key 가 눌린 회수를 MSB 1 Byte에 저장 하여 Return 한다. key_scan: push AC0 push AC1 push ZL push ZH push colData push colScanCounter // pressedKeyNum 초기화 clr pressedKeyNum clr keyCode // 모든 Key가 Release 된 경우 zero를 Return ldi ZL,lo8(key_code_table) // ldi ZH,hi8(key_code_table) // Z points to key_code_table // Row Scan Disable, Scan Port를 초기화 한다. in AC0, ROW_PORT ori AC0, ROW_MASK out ROW_PORT, AC0 key_scan1: lpm AC1, Z+ cp AC1, RG_ZERO breq key_scan4 // Row Scan Code Output in AC0, ROW_PORT com AC1 and AC0, AC1 out ROW_PORT, AC0 NOP // Get Colum Data in colData, COL_PORT_PIN andi colData, COL_MASK // Row Scan Disable in AC0, ROW_PORT ori AC0, ROW_MASK out ROW_PORT, AC0 // colData bit testing ldi colScanCounter, NUM_COLS key_scan2: mov AC0, colData andi AC0, COL_TEST brne key_scan3 // 현재 Col Key 가 Press Test lpm keyCode, Z // 현재 Col Key 가 Pressed 된 경우 get key code inc pressedKeyNum key_scan3: lpm AC0, Z+ // Z+ , AC0 값은 사용 하지 않는다. lsl colData dec colScanCounter brne key_scan2 rjmp key_scan1 key_scan4: pop colScanCounter pop colData pop ZH pop ZL pop AC1 pop AC0 ret // Return Value // RG_ARG0_L <- Char Code Data(8 Bit) // RG_ARG0_H <- Pressed Key Number // C Function : unsigned char key_scan( void ) ; keyCode 만 Return 하는 경우 // C Function : unsigned int key_scan( void ) ; keyCode를 LSB 1 Byte, // Key 가 눌린 회수를 MSB 1 Byte에 저장 하여 Return 한다. get_key: push AC0 get_key1: // Row Scan Enable in AC0, ROW_PORT andi AC0, ~ROW_MASK out ROW_PORT, AC0 nop get_key2: // Get Colum Data in colData, COL_PORT_PIN andi colData, COL_MASK cpi colData, COL_MASK brne get_key3 // Key pressed -> get_key2 // Key 가 Release 된 상태 임 lds AC0, keyPressed cpi AC0, TRUE brne get_key2 // Release 상태가 계속 되고 있다. -> get_key1 // 이제 막 Key 가 Release 됨 sts keyPressed, RG_ZERO // Key 가 Release 상태로 변경 된 것을 keyPressed 변수에 저장 한다. ldi RG_ARG0_L, DEBOUNCE_TIME // 16mSec Delay rcall delay_1mSec rjmp get_key2 // Key 가 Pressed 된 상태 임 get_key3: lds AC0, keyPressed cpi AC0, TRUE breq get_key2 // Pressed 된 상태가 계속 되고 있음 -> getkey1 // 새 Key가 이제 막 Pressed 됨 get_key4: ldi RG_ARG0_L, DEBOUNCE_TIME // 16mSec Delay rcall delay_1mSec rcall key_scan tst RG_ARG0_L // Bouncing 등의 문제로 zero 가 Return 되는 경우 다시 get_key를 실행 한다. breq get_key1 ldi AC0, TRUE // Key 가 Pressed 상태로 변경 된 것을 keyPressed 변수에 저장 한다. sts keyPressed, AC0 pop AC0 ret key_code_table: .byte 0x10,'3','2','1' .byte 0x20,'6','5','4' .byte 0x40,'9','8','7' .byte 0x80,'#','0','*' .byte 0,0,0,0 .end
• 실험을 위한 준비
• 실험 구성도를 참고하여 개발보드에 Keypad를 연결한다.
• 컴퓨터(USB --> UART(RS232) 변환 모듈)의 RXD와 Atmega128의 TXD0(PE1)를 연결한다.
• 컴퓨터(USB --> UART(RS232) 변환 모듈)의 TXD와 Atmega128의 RXD0(PE0)를 연결한다.

주: 컴퓨터에 Serial Port가 없는 경우 "USB --> UART(RS232) 변환 모듈"를 사용(USB Port를 Serial Port로 변환)하여 연결한다. 개발보드에 따라서는 "USB --> UART(RS232) 변환 모듈"을 내장하고 있는 경우가 많기 때문에 본인이 사용하는 개발보드에서 확인 하여야 한다.

참고자료: USB - Serial 변환 모듈

• 컴퓨터(USB --> UART(RS232)의 GND와 Atmega128의 GND를 연결한다. "USB --> UART(RS232) 변환 모듈"를 사용하는 경우 변환 모듈의 GND와 Atmega128의 GND를 연결한다.
• 실험 방법
• GCC_asm_keypad_uart_soft_basic.zip 파일을 Download하여 압축을 해제한다.
• Build → Build Solution 를 실행 하면 프로그램이 Build 되어 GCC_asm_keypad_uart_soft_basic.hex 파일이 생성된다.
• GCC_asm_keypad_uart_soft_basic.hex를 개발 보드에 Upload 하고 프로그램을 실행한다.

주: 모니터 프로그램(예: OC-Console, Tera Term)과 hex 파일을 Target Board에 Upload 하는 프로그램이 동일한 Port를 사용하기 때문에 모니터 프로그램을 중지하고 Upload를 실행하여야 한다.

• 모니터 프로그램(예: OC-Console, Tera Term)을 설치(이미 설치되어 있는 경우에는 실행만 하면됨)하고 실행 한다.
• 모니터 프로그램에서 필요한 설정(Serial Port와 Baudrate 등을 설정)을 한다.
• 실험:
• 개발 보드의 Reset SW를 누르면 모니터에 "KeyPad Input Testing" 메세지가 출력된다.
• Keypad에서 문자를 입력하면 입력된 문자는 UART 통신을 이용하여 모니터에 출력된다.


• External Interrupt와 Timer Interrupt를 이용한 Key debouncing과 key scan 과정에서 발생 하는 문제

External Interrupt와 Timer Interrupt를 이용한 Keypad 제어 시 아래 그림과 같이 Scan enable, disable control 과정(Key를 누르고 있는 상태가 계속되는 상태에서 Key scanning 프로그램 이 실행 되는 경우)에서 원 하지 않는 펄스(S4)가 발생 할 수 있다. 이 신호의 Falling edge(p5)에서 External Interrupt Flag 가 Set 된다. 이 External Interrupt Flag에 의하여 External Interrupt가 실행 되지 않도록 Interrupt routine 이 종료 되기 전에 이 Flag를 Clear 하여야 한다.




• 4 by 3 Keypad로 부터 Key 값을 읽어(External Interrupt와 Timer Interrupt, circular Buffer를 사용하고 Buffer overflow Testing 기능을 포함 한다.) 모니터에 출력하는 프로그램 예: GCC_asm_keypad_int_buffer_uart_timer3.zip

Keypad 초기화 와 Key scaning 함수, get_key() 함수, key_buffer, timer3_init 함수 예: GCC_asm_get_keypad_interrupt.s

// GCC_asm_get_keypad_interrupt.s // // Author: chowk // Lab: KHU // Date: 2012. 10. 10 // External Interrupt(INT4-6)과 Tmer3를 사용한 Keypad 제어 프로그램 // 이 프로그램에는 External Interrupt(INT4-6)과 Timer3의 Overflow Interrupt, // Input Buffer로 Circual Buffer 이용 하는 예를 포함 하고 있다. # ifndef atmega128 #define atmega128 # endif #define FOSC 16000000// Clock Speed #include <avr/io.h> // Definition file for ATmega128 #include "GCC_asm_uart.h" // SRAM Definitions #define _SFR_OFFSET 0 // Needed to subtract 0x20 from I/O addresses // [Add all hardware information here] // Program Constants // Program Variables Definitions #define RG_TEMP r0 // Temporary Register #define RG_ZERO r1 // Zero #define AC0 r16 // Accumulator Byte Rg 0 #define AC1 r17 // Accumulator Byte Rg 1 #define AC2 r18 // Accumulator Byte Rg 2 #define AC3 r19 // Accumulator Byte Rg 3 #define AC4 r20 // Accumulator Byte Rg 2 #define AC5 r21 // Accumulator Byte Rg 2 #define ACW0_L r2 // Accumulator Word Rg 0 Low #define ACW0_H r3 // Accumulator Word Rg 0 High #define ACW1_L r4 // Accumulator Word Rg 1 Low #define ACW1_H r5 // Accumulator Word Rg 1 High #define ACW2_L r6 // Accumulator Word Rg 2 Low #define ACW2_H r7 // Accumulator Word Rg 2 High #define ACW3_L r8 // Accumulator Word Rg 3 Low #define ACW3_H r9 // Accumulator Word Rg 3 High #define RG_ARG0_H r25 // Function Argument Word Rg 0 High #define RG_ARG0_L r24 // Function Argument Word Rg 0 Low #define RG_ARG1_H r23 // Function Argument Word Rg 1 High #define RG_ARG1_L r22 // Function Argument Word Rg 1 Low #define RG_ARG2_H r21 // Function Argument Word Rg 2 High #define RG_ARG2_L r20 // Function Argument Word Rg 2 Low #define BUFFER_FULL_FLAG r18 // Buffer full error flag #define ROW_PORT _SFR_IO_ADDR(PORTC) // Output Port #define ROW_PORT_DDR _SFR_IO_ADDR(DDRC) #define COL_PORT _SFR_IO_ADDR(PORTE) // Input Port #define COL_PORT_DDR _SFR_IO_ADDR(DDRE) #define COL_PORT_PIN _SFR_IO_ADDR(PINE) // Input Port #define ROW_MASK 0xf0 #define COL_MASK 0x70 #define NUM_ROWS 4 #define NUM_COLS 3 #define COL_TEST 0x40 // NUM_COLS = 3 : 0x40, NUM_COLS =4 : 0x80 #define TRUE 0xff #define FALSE 0x00 #define TIMER3_16mSEC_DELAY_LOW 0x5f #define TIMER3_16mSEC_DELAY_HIGH 0xf0 .section .data keyPressed: .byte FALSE // Key 상태(Pressed or Release)을 저장하기 위한 변수 // key_code_table은 .text 아래에 위치한다. key_buffer: .byte 0,1,2,3,4,5,6,7 key_buffer_end: key_get_pt: .word 0x0000 key_put_pt: .word 0x0000 buffer_data_size: .byte 0x00 .section .text // Interrupt vector Table에 INT4_vect,INT5_vect,INT6_vect의 Interrupt vector를 설정 한다. .global INT4_vect,INT5_vect,INT6_vect,TIMER3_OVF_vect .global keypad_init,get_key timer3_init: // C Function : void timer3_init(void); push AC0 in AC0,_SFR_IO_ADDR(SREG) // Status register를 Save 한다. push AC0 cli // Disable interrupts // Normal port operation. // Clock Selection : Clk / 64 -> 4uSec ldi AC0, (0 << CS32) | (1 << CS31) | (1 << CS30) sts TCCR3B, AC0 // Overflow Interrupt 를 사용하기 때문에 16mSec 주기를 발생 하기 위하여 // 65535 - 4000 = 61535(0xf05f)를(16mSec = 4uSec * 4000) TCNT0 값을 설정여야 한다. // TIM16_WriteTCNTn: ldi AC0, TIMER3_16mSEC_DELAY_HIGH sts TCNT3H, AC0 // Set TCNTn to r17:r16 ldi AC0, TIMER3_16mSEC_DELAY_LOW sts TCNT3L, AC0 // Timer3 Over Flow Interrupt Disable lds AC0, ETIMSK andi AC0, ~(1 << TOIE3) // Clear : TOIE3 sts ETIMSK, AC0 pop AC0 out _SFR_IO_ADDR(SREG), AC0 pop AC0 ret // C Function : void keypad_port_init(void); keypad_port_init: push AC0 // ROW_PORT &= (~ROW_MASK) // Key Scan Output Port Enable <- 0 in AC0, ROW_PORT andi AC0, ~ROW_MASK out ROW_PORT, AC0 // Row Port Init(PC7-PC4 <- 0) // ROW_PORT_DDR |= ROW_MASK // Key Scan Output Port : PC4-PC7 in AC0, ROW_PORT_DDR ori AC0, ROW_MASK out ROW_PORT_DDR, AC0 // PORTE |= COL_MASK // External SW PullUp in AC0, COL_PORT // Input Port Pull Up ori AC0, COL_MASK out COL_PORT, AC0 // Col Port Init(PE6-PE4 <- 1) // COL_PORT_DDR &= (~COL_MASK) in AC0, COL_PORT_DDR andi AC0, ~COL_MASK out COL_PORT_DDR, AC0 // Col Port <- Input Port(PE6-PE4 <- Input Port) // External Interrupt Sensing Port : SW Interrupt(PE4 - PE6) // External Interrupt 4 - 6 ,Falling edge between two samples of INTn ldi AC0, 0xaa out _SFR_IO_ADDR(EICRB), AC0 // External Interrupt flag ,clear lds AC0, EIFR ori AC0, COL_MASK sts EIFR, AC0 // External Interrupt 4 - 6 ,enable lds AC0, EIMSK ori AC0, COL_MASK sts EIMSK, AC0 sei pop AC0 ret key_buffer_init: push AC0 push ZL push ZH // buffer_data_size 초기화 sts buffer_data_size, RG_ZERO // key_put_pt, key_get_pt의 Low Byte를 초기화 ldi AC0, lo8(key_buffer) sts key_put_pt, AC0 sts key_get_pt, AC0 // key_put_pt, key_get_pt의 High Byte를 초기화 ldi AC0, hi8(key_buffer) sts key_put_pt+1, AC0 sts key_get_pt+1, AC0 pop ZH pop ZL pop AC0 ret keypad_init: rcall timer3_init rcall keypad_port_init sts keyPressed, RG_ZERO // keyPressed의 초기 상태를 FALSE 로 설정 rcall key_buffer_init ret //Calling Sequence // RG_ARG0_L <- Put char code //Return Value // RG_ARG0_L <- Buffer Full 인 경우 zero를 Return // put_char_buf 함수가 성공적으로 실행 된 경우 RG_ARG0_L 값이 변동 없이 Return 된다. // C Function : unsigned char put_char_buf( char ) ; put_char_buf: push AC0 push YL push YH push ZL push ZH // Buffer full test lds AC0, buffer_data_size cpi AC0, (key_buffer_end - key_buffer) //buffer_data_size brne put_char_buf1 // Buffer full 이 아니면 data를 buffer에 put // Set buffer full error flag ser BUFFER_FULL_FLAG clr RG_ARG0_L // Buffer full 일 경우 zero를 Return rjmp end_put_char_buf put_char_buf1: // Buffer에 저장된 Data의 갯수를 1 만큼 증가 한다. inc AC0 sts buffer_data_size, AC0 // data를 Buffer에 저장 한다. ldi ZL, lo8(key_put_pt) ldi ZH, hi8(key_put_pt) // key_put_pt 저장 번지로 부터 poiter 값을 읽는다. ld YL, Z+ ld YH, Z st Y+, RG_ARG0_L // Buffer에 Data를 저장 한다. // Buffer pointer 가 buffer의 끝에 도달 하였는지 Test ldi AC0, lo8(key_buffer_end) cp AC0, YL brne put_char_buf2 ldi AC0, hi8(key_buffer_end) cp AC0, YH brne put_char_buf2 // Buffer pointer 가 buffer의 끝에 도달한 경우 Buffer Pt 를 Buffer의 시작 번지로 초기화 sbiw ZL, 1 ldi AC0, lo8(key_buffer) st Z+, AC0 // Buffer Pt는 Word Data data. ldi AC0, hi8(key_buffer) st Z, AC0 rjmp end_put_char_buf put_char_buf2: sbiw ZL, 1 st Z+, YL // key_put_pt를 저장 한다.. st Z, YH end_put_char_buf: pop ZH pop ZL pop YH pop YL pop AC0 ret // Return Value // RG_ARG0_L <- 함수가 성공적으로 실행 된 경우 Char data(8 Bit) // RG_ARG0_L <- zero : Buffer 가 비어 있는 경우 zero를 Return // C Function : unsigned char get_char_buf( void ); get_char_buf: push AC0 push YL push YH push ZL push ZH // Buffer empty 일 경우 zero를 Return clr RG_ARG0_L // Buffer empty test lds AC0, buffer_data_size tst AC0 breq end_get_char_buf // Buffer empty 면 RG_ARG0_L <- 0, Return get_char_buf1: // Buffer에 저장된 Data의 갯수를 1 만큼 감소 시킨다. dec AC0 sts buffer_data_size, AC0 // Buffer의 Data를 읽는다. ldi ZL, lo8(key_get_pt) ldi ZH, hi8(key_get_pt) ld YL, Z+ ld YH, Z ld RG_ARG0_L, Y+ // Buffer pointer 가 buffer의 끝에 도달 하였는지 Test ldi AC0, lo8(key_buffer_end) cp AC0, YL brne get_char_buf2 ldi AC0, hi8(key_buffer_end) cp AC0, YH brne get_char_buf2 // Buffer pointer 가 buffer의 끝에 도달한 경우 Buffer Pt 를 Buffer의 시작 번지로 초기화 sbiw ZL, 1 ldi AC0, lo8(key_buffer) st Z+, AC0 // Buffer Pt는 16bit(2 Byte). ldi AC0, hi8(key_buffer) st Z, AC0 rjmp end_get_char_buf get_char_buf2: sbiw ZL, 1 st Z+, YL // key_get_pt를 저장 한다.. st Z, YH end_get_char_buf: pop ZH pop ZL pop YH pop YL pop AC0 ret #define rowScanCode r18 #define colData r19 #define rowScanCounter r20 #define colScanCounter r21 #define pressedKeyNum r25 #define keyCode r24 // Key Scan // Return Value // RG_ARG0_L <- Char Code Data(8 Bit) // RG_ARG0_H <- Pressed Key Number // rcall key_scan // C Function : unsigned char key_scan( void ); keyCode 만 Return 하는 경우 // C Function : unsigned int key_scan( void ); keyCode를 LSB 1 Byte, // Key 가 눌린 회수를 MSB 1 Byte에 저장 하여 Return 한다. key_scan: push AC0 push AC1 push ZL push ZH push colData push colScanCounter // pressedKeyNum 초기화 clr pressedKeyNum clr keyCode // 모든 Key가 Release 된 경우 zero를 Return ldi ZL,lo8(key_code_table) // ldi ZH,hi8(key_code_table) // Z points to key_code_table // Row Scan Disable, 이전 Row Port의 상태를 초기화 하기 위한 것 임. in AC0, ROW_PORT ori AC0, ROW_MASK out ROW_PORT, AC0 key_scan1: lpm AC1, Z+ cp AC1, RG_ZERO breq key_scan4 // Row Scan Code Output in AC0, ROW_PORT com AC1 and AC0, AC1 out ROW_PORT, AC0 nop // Get Colum Data in colData, COL_PORT_PIN andi colData, COL_MASK // Row Scan Disable in AC0, ROW_PORT ori AC0, ROW_MASK out ROW_PORT, AC0 // colData bit testing ldi colScanCounter, NUM_COLS key_scan2: mov AC0, colData andi AC0, COL_TEST brne key_scan3 // 현재 Col Key 가 Press Test lpm keyCode, Z // 현재 Col Key 가 Pressed 된 경우 get key code inc pressedKeyNum key_scan3: adiw ZL, 1 lsl colData dec colScanCounter brne key_scan2 rjmp key_scan1 key_scan4: pop colScanCounter pop colData pop ZH pop ZL pop AC1 pop AC0 ret // Return Value // RG_ARG0_L <- Char Code Data(8 Bit) // RG_ARG0_H <- Pressed Key Number // C Function : unsigned char key_scan( void ) ; keyCode 만 Return 하는 경우 // C Function : unsigned int key_scan( void ) ; keyCode를 LSB 1 Byte, // Key 가 눌린 회수를 MSB 1 Byte에 저장 하여 Return 한다. get_key: rcall get_char_buf tst RG_ARG0_L // Buffer가 empty 상태인 경우 zero가 Return 된다. breq get_key // zero 가 Return 되지 않을 때 까지 기다린다. ret INT4_vect: INT5_vect: INT6_vect: push AC0 // Status register is not automatically stored when entering an interrupt routine in AC0,_SFR_IO_ADDR(SREG) // Status register를 Save 한다. push AC0 // External Interrupt 4 - 6 ,disable lds AC0, EIMSK andi AC0, ~(COL_MASK) sts EIMSK, AC0 // TIM16_WriteTCNTn: // Timer3의 TCNT3 값은 TCN3L 값을 Write 할 때 동시에 2Byte 가 쓰여 지기 때문에 // sts TCNT3H,AC0 명령 실행 후 다른 Interrupt 가 발생 하여 sts TCNT3L,AC0 명령 // 실행 전에 TCNT3H 이 변경 되어 서는 않된다. cli // Disable interrupts ldi AC0, TIMER3_16mSEC_DELAY_HIGH sts TCNT3H,AC0 // 16mSec Delay ldi AC0, TIMER3_16mSEC_DELAY_LOW sts TCNT3L,AC0 // Timer3 overflow flag ,clear lds AC0, ETIFR ori AC0, (1 << TOV3) sts ETIFR, AC0 // Timer3 overflow interrupt enable lds AC0, ETIMSK ori AC0, (1 << TOIE3) sts ETIMSK, AC0 pop AC0 out _SFR_IO_ADDR(SREG), AC0 pop AC0 reti TIMER3_OVF_vect: push AC0 // Status register is not automatically stored when entering an interrupt routine in AC0, _SFR_IO_ADDR(SREG) // Status register를 Save 한다. push AC0 push colData // Timer3 overflow interrupt disable lds AC0, ETIMSK andi AC0, ~(1 << TOIE3) sts ETIMSK, AC0 // Row Scan Enable in AC0, ROW_PORT andi AC0, ~ROW_MASK out ROW_PORT, AC0 nop // Get Colum Data in colData, COL_PORT_PIN andi colData, COL_MASK cpi colData, COL_MASK breq timer3_1 // Key Release -> get_key2 // Key 가 Pressed 된 상태 임 rcall key_scan tst RG_ARG0_L breq timer3_1 // rcall ASM_putchar rcall put_char_buf // RG_ARG0_L의 Data는 Buffer에 저장 하였기 때문에 // get_char에서 다시 사용 되는 것을 방지 하기 위함. clr RG_ARG0_L timer3_1: // Row Scan Enable in AC0, ROW_PORT andi AC0, ~ROW_MASK out ROW_PORT, AC0 // External Interrupt flag ,clear lds AC0, EIFR ori AC0, COL_MASK sts EIFR, AC0 // External Interrupt 4 - 6 ,enable lds AC0, EIMSK ori AC0, COL_MASK sts EIMSK, AC0 pop colData pop AC0 out _SFR_IO_ADDR(SREG), AC0 pop AC0 reti key_code_table: .byte 0x10,'3','2','1' .byte 0x20,'6','5','4' .byte 0x40,'9','8','7' .byte 0x80,'#','0','*' .byte 0,0,0,0 .end
• 실험을 위한 준비
• 실험 구성도를 참고하여 개발보드에 Keypad를 연결한다.
• 컴퓨터(USB --> UART(RS232) 변환 모듈)의 RXD와 Atmega128의 TXD0(PE1)를 연결한다.
• 컴퓨터(USB --> UART(RS232) 변환 모듈)의 TXD와 Atmega128의 RXD0(PE0)를 연결한다.

주: 컴퓨터에 Serial Port가 없는 경우 "USB --> UART(RS232) 변환 모듈"를 사용(USB Port를 Serial Port로 변환)하여 연결한다. 개발보드에 따라서는 "USB --> UART(RS232) 변환 모듈"을 내장하고 있는 경우가 많기 때문에 본인이 사용하는 개발보드에서 확인 하여야 한다.

참고자료: USB - Serial 변환 모듈

• 컴퓨터(USB --> UART(RS232)의 GND와 Atmega128의 GND를 연결한다. "USB --> UART(RS232) 변환 모듈"를 사용하는 경우 변환 모듈의 GND와 Atmega128의 GND를 연결한다.
• 실험 방법
• GCC_asm_keypad_int_buffer_uart_timer3.zip 파일을 Download하여 압축을 해제한다.
• Build → Build Solution 를 실행 하면 프로그램이 Build 되어 GCC_asm_keypad_int_buffer_uart_timer3.hex 파일이 생성된다.
• GCC_asm_keypad_int_buffer_uart_timer3.hex를 개발 보드에 Upload 하고 프로그램을 실행한다.

주: 모니터 프로그램(예: OC-Console, Tera Term)과 hex 파일을 Target Board에 Upload 하는 프로그램이 동일한 Port를 사용하기 때문에 모니터 프로그램을 중지하고 Upload를 실행하여야 한다.

• 모니터 프로그램(예: OC-Console, Tera Term)을 설치(이미 설치되어 있는 경우에는 실행만 하면됨)하고 실행 한다.
• 모니터 프로그램에서 필요한 설정(Serial Port와 Baudrate 등을 설정)을 한다.
• 실험:
• 개발 보드의 Reset SW를 누르면 모니터에 "KeyPad Input Testing" 메세지가 출력된다.
• Keypad에서 문자를 입력하면 입력된 문자는 UART 통신을 이용하여 모니터에 출력된다.
• SW PD0를 누르고 keypad의 key를 입력 하면 입력된 Data가 Buffer에 저장 되고 출력 되지 않는다. 입력된 Data의 수가 Buffer 크기를 초과하면 "Buf Full Error" 메세지가 출력된다.
• 하나의 Keypad로 부터 서로 다른 2개의 Key code을 읽어 모니터에 출력하는 프로그램 예

4 by 3 Keypad로 부터 Multi Code Key 값을 읽어 모니터에 출력하는 프로그램 예

• 실험을 위한 준비
• 실험 구성도를 참고하여 개발보드에 Keypad를 연결한다.
• 컴퓨터(USB --> UART(RS232) 변환 모듈)의 RXD와 Atmega128의 TXD0(PE1)를 연결한다.
• 컴퓨터(USB --> UART(RS232) 변환 모듈)의 TXD와 Atmega128의 RXD0(PE0)를 연결한다.

주: 컴퓨터에 Serial Port가 없는 경우 "USB --> UART(RS232) 변환 모듈"를 사용(USB Port를 Serial Port로 변환)하여 연결한다. 개발보드에 따라서는 "USB --> UART(RS232) 변환 모듈"을 내장하고 있는 경우가 많기 때문에 본인이 사용하는 개발보드에서 확인 하여야 한다.

참고자료: USB - Serial 변환 모듈

• 컴퓨터(USB --> UART(RS232)의 GND와 Atmega128의 GND를 연결한다. "USB --> UART(RS232) 변환 모듈"를 사용하는 경우 변환 모듈의 GND와 Atmega128의 GND를 연결한다.
• 실험 방법
• GCC_c_asm_keypad_multi_uart_io_basic.zip 파일을 Download하여 압축을 해제한다.
• Build → Build Solution 를 실행 하면 프로그램이 Build 되어 GCC_c_asm_keypad_multi_uart_io_basic.hex 파일이 생성된다.
• GCC_c_asm_keypad_multi_uart_io_basic.hex를 개발 보드에 Upload 하고 프로그램을 실행한다.

주: 모니터 프로그램(예: OC-Console, Tera Term)과 hex 파일을 Target Board에 Upload 하는 프로그램이 동일한 Port를 사용하기 때문에 모니터 프로그램을 중지하고 Upload를 실행하여야 한다.

• 모니터 프로그램(예: OC-Console, Tera Term)을 설치(이미 설치되어 있는 경우에는 실행만 하면됨)하고 실행 한다.
• 모니터 프로그램에서 필요한 설정(Serial Port와 Baudrate 등을 설정)을 한다.
• 실험:
• 개발 보드의 Reset SW를 누르면 모니터에 "Input Keypad, Output Uart", ": Key Code Table Change Key ", "# Key: CR Code"메세지가 출력된다.
• key_code_table1 이 선택된 경우 Keypad에서 문자를 입력하면 숫자가 UART 통신을 이용하여 모니터에 출력되고, key_code_table2 가 선택된 경우 Keypad에서 문자를 입력하면 문자가 모니터에 출력된다.
• * Key를 누르면 Key code table이 변경되어 현재 숫자가 출력되는 경우 문자가 출력된다. 만약 현재 문자가 출력되는 경우에는 숫자가 출력된다.
• # Key는 CR Code로 사용된다.

Switch debouncing 과 Keypad Interfacing 관련 페이지 보기

• ATmega128 I/O Port - ASM
• ATMega128 External Interrupt - ASM
• Serial I/O(UART) Communication - ASM